plugins {
    id 'java'
    id("xyz.jpenilla.run-paper") version "2.3.1"
    id 'com.gradleup.shadow' version '9.0.0-beta10'
}

group = 'me.trouper'
version = '1.0.0'

repositories {
    mavenCentral()
    mavenLocal()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
    maven {
        url = uri("https://repo.codemc.io/repository/maven-releases/")
    }
    maven {
        url = uri("https://repo.codemc.io/repository/maven-snapshots/")
    }
    maven{
        url = uri("https://jitpack.io")
    }
    maven {
        name = "CodeMC"
        url = uri("https://repo.codemc.io/repository/maven-public/")
    }
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT")
    compileOnly("com.github.retrooper:packetevents-spigot:2.8.0")
    compileOnly("com.gitlab.ruany:LiteBansAPI:0.6.1")
    compileOnly("de.tr7zw:item-nbt-api-plugin:2.15.0")
    implementation("me.trouper:alias:1.0-1.21.1-SNAPSHOT")
    implementation("club.minnced:discord-webhooks:0.8.4")
}

tasks {
    runServer {
        minecraftVersion("1.21.5")
    }
}

def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    minimize()
}

task uploadPlugin(type: JavaExec) {
    dependsOn(shadowJar)

    mainClass = 'me.trouper.uploader.Uploader'
    classpath = project(':Uploader').sourceSets.main.runtimeClasspath

    def shadowJar = tasks.named("shadowJar").get().archiveFile.get().asFile
    args = [shadowJar.absolutePath]
}